Időzóna: UTC + 1 óra [ nyi ]




Új téma nyitása Hozzászólás a témához  [ 238 hozzászólás ]  Oldal 1, 2, 3, 4, 5 ... 12  Következő
Szerző Üzenet
  Offline
 Hozzászólás témája: WoG Scriptek
HozzászólásElküldve: 2003 szept. 04 csüt., 19:20 
Avatar

Csatlakozott: 2003 júl. 13 vas., 16:10
Hozzászólások: 260
Tartózkodási hely: Szeged
Ezt a részt azért hozom lérte, hogy ha valakinek van valamilyen scriptje, akkor az megoszhassa a többiekkel.
Itt is van egy egyszerű:
Kód:
ZVSE
!#VRz109:S^Digging house^;
!#OB63/64:H190;
!?OB63/64;
!!UN:U54/0/?v98;
!!IF&v98>0:M^A group of guarding pikemen dig a hole, until they reach water.^;
!!IF&v98=0:M^There are no pikemen on th map.^;
!!UN&v98>0:U54/0/1/5;
!!UN&v98>0:Ov5/v6/v7;
!!TRv5/v6/v7&v98>0:T8/20/0/0/0/0/0/0;

Ez egy olyan házat hoz lérte, amit ha meglátogatunk, akkor a térképen lévő egyik pikeman csoportot vízzé alakítja. (A ház az utolsó előtti sor 3. oszlopában van)

Koordináta lekérdezés:
Kód:
ZVSE
!?CM:I5;
!!HE-1:P?v100/?v101/?v102;
!!VRz100:S^You are at %V100 %V101 %V102.^;
!!QW:A1/-1/-1/100;


Ezzel pl. meg lehet oldani, hogy egy pályán a grail helyét ne a puzzle map-ból találd ki, hanem mondjuk egy küldetésért cserébe megkapod a koordinátáit.
Használat: Állj a megfelelő helyre, aztán jobb klikk a quest logra, majd a hősödnél lévő quest logra bal klikk. (A játék első napján ne használjátok!!!)

ui.: Vicces, ha az ember 7 év után javítgatja a hozzászólásait.


A hozzászólást 6 alkalommal szerkesztették, utoljára Fizban 2011 feb. 27 vas., 13:54-kor.

Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 04 csüt., 19:30 
Avatar
a verbális armageddon

Csatlakozott: 2003 júl. 22 kedd, 18:23
Hozzászólások: 485
Tartózkodási hely: Komárom
Folytatva Fizbant:

1.script

ZVSE

** Script for changing the characteristics of Nightmare

[Event on #1 #2 #3]
!?LE9/55/0;

[Monster # is now considered a Level $ monster]
!!MA:L172/7;

[Monster # has a Grow rate of $]
!!MA:G172/2;

[Monster # has $ Hit Points]
!!MA:P172/400;

[Monster # has an Attack of $]
!!MA:A172/30;

[Monster # has a Defence of $]
!!MA:D172/30;

[Monster # has a Damage Low of $]
!!MA:M172/40;

[Monster # has a Damage High of $]
!!MA:E172/60;

[Monster # Costs resource #2 to buy]
!!MA:C172/6/5000C172/5/5;

** End of Script **

-----------------------------------------------------------------------------
2.script


ZVSE



** Object location: x=10, y=36, level=0
** Gods Snow Rock, Place Castle Town on map

!#TR10/36/0:P1; [to make passable]
!#TR10/36/0:E0; [yellow trigger]
!#OB10/36/0:T81; [to turn into another object]
!#VRz1:S^Gods Snow Rock^; [right-click hint text]
!#OB10/36/0:H1;
!?OB10/36/0; [object trigger]
** Place Castle Town on map
!!IF:M^As you ride into a clearing, you notice a Gods Snow Rock, one of the legendary Gods rocks.^;
!!UN:I8/46/0/98/0; [Place Castle]
!!CA8/46/0:N^Paligrano^;
!!IF:M^You take this Gods Snow Rock and he create a Castle Town in your nearness.^;



** Object location: x=28, y=46, level=0
** Gods Sand Rock, Transform Gold Dragons into Azure Dragons

!#TR28/46/0:P1; [to make passable]
!#TR28/46/0:E0; [yellow trigger]
!#OB28/46/0:T81; [to turn into another object]
!#VRz2:S^Gods Sand Rock^; [right-click hint text]
!#OB28/46/0:H2;
!?OB28/46/0; [object trigger]
** Transform Gold Dragons into Azure Dragons
!!IF:M^As you ride into a clearing, you notice a Gods Sand Rock, one of the legendary Gods rocks.^;
!!HE-1:X6/27/27/132;
!!IF:Q1/21/132/1^You take this Gods Sand Rock and he give you ability to transform Gold Dragons into Azure Dragons.^; [Display picture of new creatures]



** Object location: x=47, y=56, level=0
** Gods Lava Rock, +6 Atack

!#TR47/56/0:P1; [to make passable]
!#TR47/56/0:E0; [yellow trigger]
!#OB47/56/0:T81; [to turn into another object]
!#VRz3:S^Gods Lava Rock^; [right-click hint text]
!#OB47/56/0:H3;
!?OB47/56/0; [object trigger]
** Add +6 to the visiting heroe's Atack
!!IF:M^As you ride into a clearing, you notice a Gods Lava Rock, one of the legendary Gods rocks.^;
!!HE-1:F?v1/d0/d0/d0;
!!VRv1:+6;
!!HE-1:Fv1/d0/d0/d0;
!!IF:Q1/31/6/1^You take this Gods Lava Rock and he give you some advance skills.^; [Display picture of atack points bonus]



** Object location: x=59, y=15, level=0
** Gods Brown Rock, +6 Defense

!#TR59/15/0:P1; [to make passable]
!#TR59/15/0:E0; [yellow trigger]
!#OB59/15/0:T81; [to turn into another object]
!#VRz4:S^Gods Brown Rock^; [right-click hint text]
!#OB59/15/0:H4;
!?OB59/15/0; [object trigger]
** Add +6 to the visiting heroe's Defense
!!IF:M^As you ride into a clearing, you notice a Gods Brown Rock, one of the legendary Gods rocks.^;
!!HE-1:Fd0/?v2/d0/d0;
!!VRv2:+6;
!!HE-1:Fd0/v2/d0/d0;
!!IF:Q1/32/6/1^You take this Gods Brown Rock and he give you some advance skills.^; [Display picture of defense points bonus]



** Object location: x=30, y=24, level=0
** Gods Swamp Rock, +3 Power Skill & +3 Knowledge

!#TR30/24/0:P1; [to make passable]
!#TR30/24/0:E0; [yellow trigger]
!#OB30/24/0:T81; [to turn into another object]
!#VRz5:S^Gods Swamp Rock^; [right-click hint text]
!#OB30/24/0:H5;
!?OB30/24/0; [object trigger]
** Add +3 to the visiting heroe's Power Skill & Knowledge
!!IF:M^As you ride into a clearing, you notice a Gods Swamp Rock, one of the legendary Gods rocks.^;
!!HE-1:Fd0/d0/?v3/?v4;
!!VRv3:+3;
!!VRv4:+3;
!!HE-1:Fd0/d0/v3/v4;
!!IF:Q1/33/3/34/3/1^You take this Gods Swamp Rock and he give you some advance skills.^; [Display pictures of power skill & knowledge points bonus]



** Object location: x=69, y=59, level=0
** Gods Rough Rock, +50000 Experience

!#TR69/59/0:P1; [to make passable]
!#TR69/59/0:E0; [yellow trigger]
!#OB69/59/0:T81; [to turn into another object]
!#VRz6:S^Gods Rough Rock^; [right-click hint text]
!#OB69/59/0:H6;
!?OB69/59/0; [object trigger]
** Add +50000 to the visiting heroe's Experience
!!IF:M^As you ride into a clearing, you notice a Gods Rough Rock, one of the legendary Gods rocks.^;
!!HE-1:E?v5;
!!VRv5:+50000;
!!HE-1:Ev5;
!!IF:Q1/17/50000/1^You take this Gods Rough Rock and he give you some advance skills.^; [Display picture of experience points bonus]



** Object location: x=68, y=35, level=0
** Gods Dirt Rock, Place a couple of Two Way Monoliths on map

!#TR68/35/0:P1; [to make passable]
!#TR68/35/0:E0; [yellow trigger]
!#OB68/35/0:T81; [to turn into another object]
!#VRz7:S^Gods Dirt Rock^; [right-click hint text]
!#OB68/35/0:H7;
!?OB68/35/0; [object trigger]
** Place couple of Two Way Monoliths on map
!!IF:M^As you ride into a clearing, you notice a Gods Dirt Rock, one of the legendary Gods rocks.^;
!!UN:I56/70/1/45/3; [Place first Monolith]
!!UN:I1/38/1/45/3; [Place second Monolith]
!!IF:M^You take this Gods Dirt Rock and he create somewhere a couple of Two Way Monoliths.^;

-----------------------------------------------------------
3.script-napalm bomb


ZVSE
AUTO_PoweredBy=ERM Script Editor v.1.2.6.32

[Check battle location]
!?BA0;
!!BA:P?v1/?v2/?v3;[Location: v1/v2/v3]
!!OB1:T?v4;[Type of object at battle site: v4=98 if a town]
!!BA:H0/?v5;[Attacking hero in v5]
!!HEv5:S10/?v6;[Ballistics skill in v6]
!!IF:V295/0;[Set flag 295 initially to false]
!!IF|v4=98/v6=0:V295/1;[Set flag 295 to trueif it's a town or herodoes'nt have ballistic skill]]
!!VRv7:Sv6 *50;[Low damage]
!!VRv8:Sv6 *100;[High damage]
!!MA&-295:X145/?v291;[Store Catapult flags]
!!MA&-295:X145/d-32 M145/v7 E145/v8;[Change Catapult damage]


!?BF&-295;
!!BU:S145/1/88/0/-1/0;[Add a catapult to attacker's army at position 88]
!!DO19100/0/21/1:P;[FindCatapult stack and change it to Magogs]

!?FU19100;
!!BMx16:T?y1;[Type in y1]
!!VRv290&y1=145:Sx16;[Stack number of Catapult in v290]
!!VRz850&y1=145:S^Napalm Thrower^;
!!UN&y1=145:G1/45/0/850;[Change Magog name to "Napalm Thrower"]
!!BMv290&y1=145:T45;[Change Cataput into Magog]
!!BMv290&y1=145:Fd64;[Add "War Machine" flag to Catapult stack]

!?BG0;
!!BG:A?v1 N?v2;[Checktype of action: v1, Stacknumber: v2]
!!BMv2:T?v3;[Check type of creature: v3]
!!VRv4:S0;
!!BMv290&v2=v290/v3=45:R0;[Set Catapults retaliation to zero]
!!BG&v2=v290/v3=45/v1=2:S0;[Cancel if Catapult tries to walk]
!!BG&v2=v290/v3=45/v1=6:S7;[If Catapult tries to attack, make it shoot]

!?BA1&-295;
!!MA:X145/v291;[Restore Catapult flags]
!!UN:G1/45/0/0;[Restore Magog name]

---------------------------------------------------
4.script

ZVSE
AUTO_PoweredBy=ERM Script Editor v.1.2.6.32

!#MA:X105/d65536;[Give Dragon Flies No Retaliation]

!?BG0;[Before Action]
!!IF:V299/0;[Set flag299 to 0]
!!BG:N?v299 A?v295;[get stack number:v296,action type:v295]
!!BMv299:T?v298;[Get monster type: 105=Dragon Flies]
!!FU19000&v298=105/v295=6:P;[Call function if Dragon Fly and action is Attacking]

!?FU19000;[Dragon Flies and Attack action]
!!VRv297:S-1;[Postion Default -1]
!!BMv299:P?v297;[Get Position]
!!BGv299:E?v296;[Get Target]
!!IF:V299/1;[Set flag 299 to 1]

!?BG1&299;[after action - only if Flag 299 is set to 1]
!!IF&299:V298/0;[default for 298(valid target)=0]
!!IF&v296>-1/299:V298/1;[if target is stack then set 298]
!!BMv296&299/298:M59/1/0;[put spell on target]
[!!BMv299&299/298:Pv297;] [set position disrupts graphics]
!!BG&299/298:Dv297;[set walk target]
!!BG&299/298:A2;[walk]

------------------------------------------------------------
5.script-temple of might ,25 peasantot alakít át

ZVSE
*/ Temple of Might ERM script v1.1 --- wolfmah
*/ Requires WOG 3.53 or later
*/
*/ This script will allow you to use one of the hero that have a creature
*/ speciality and when he visit one of the temple (the object below the big
*/ Icy Mushroom) place on the map and got some Peasants with him, he will be
*/ able to upgrade them into his speciality. The cost will be the difference
*/ between the Peasant and the creature. In other word, it works just like the
*/ Hill Fort, except it only work with hero that have a creature speciality and
*/ Peasants on them.
*/
*/ To use this script, copy and paste it in a global event on a map, set it to
*/ never happen (minimum of 500 day) and uncheck all colours.
*/
*/ Variable and Function used :
*/ Q100 - 101 - 111 - 113 - 115 - 117 - 119 - 121 - 123 - 125 - 128 - 129 - 130
*/ z10
*/ v110 - 111 - 112 - 113 - 114 - 115 - 116 - 117 - 118 - 119 - 120 - 121 -
*/ 122 - 123 - 124 - 125
*/ FU1 - 2

*/ Set up hint text for "Temple of Might" objects
!#VRz10:S^Temple of Might^;
!#HT63/21:T10;

!?OB63/21; */ Triggers when any Temple of Might is visited

!!IF:V111/0; */ Will be use to know if the hero got at least 1 Peasant
!!IF:V113/0;
!!IF:V115/0;
!!IF:V117/0;
!!IF:V119/0;
!!IF:V121/0;
!!IF:V123/0;

!!IF:M^You enter the Temple of Might and hear a voice...^;
!!IF:M^Hi there traveler, here is the Temple of Might. In this place, all the hero who got creature speciality and Peasants can upgrade them, thank to my magic, into there speciality. Now, let me check if you worth my time.^;

!!HE-1:N?v110; */ Get the number of the hero
!!HE-1:C0/0/?v111/?v112; */ Slot 1
!!HE-1:C0/1/?v113/?v114; */ Slot 2
!!HE-1:C0/2/?v115/?v116; */ Slot 3
!!HE-1:C0/3/?v117/?v118; */ Slot 4
!!HE-1:C0/4/?v119/?v120; */ Slot 5
!!HE-1:C0/5/?v121/?v122; */ Slot 6
!!HE-1:C0/6/?v123/?v124; */ Slot 7

!!IF&v111=139:V111/1; */ Check which slot got Peasants
!!IF&v113=139:V113/1;
!!IF&v115=139:V115/1;
!!IF&v117=139:V117/1;
!!IF&v119=139:V119/1;
!!IF&v121=139:V121/1;
!!IF&v123=139:V123/1;

!!VRv125:S0; */ The sum of all the Peasants in each slot
!!VRv125&111:+v112;
!!VRv125&113:+v114;
!!VRv125&115:+v116;
!!VRv125&117:+v118;
!!VRv125&119:+v120;
!!VRv125&121:+v122;
!!VRv125&123:+v124;

!!IF&v125=0:M^If you don't have at least 1 Peasant, there is nothing to do here, so please, leave.^;

*/ Check the hero and asign the right parameters
*/ Knight- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=146/v125>0:P6/v125; */ Catherine - Swordsmen
!!FU1&v110=2/v125>0:P4/v125; */ Edric - Griffins
!!FU1&v110=152/v125>0:P6/v125; */ Roland - Swordsmen
!!FU1&v110=5/v125>0:P6/v125; */ Sorsha - Swordsmen
!!FU1&v110=7/v125>0:P10/v125; */ Tyris - Cavaliers
!!FU1&v110=1/v125>0:P2/v125; */ Valeska - Archers
*/ Cleric- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=12/v125>0:P8/v125; */ Ingham - Monks
*/ Ranger- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=22/v125>0:P24/v125; */ Clancy - Unicorns
!!FU1&v110=21/v125>0:P18/v125; */ Ivor - Wood Elves
!!FU1&v110=19/v125>0:P22/v125; */ Ryland - Dendroids Guards
!!FU1&v110=17/v125>0:P16/v125; */ Ufretin - Dwarves
*/ Druid - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=31/v125>0:P20/v125; */ Aeris - Pegasi
*/ Alchemist - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=37/v125>0:P38/v125; */ Fafner - Nagas
!!FU1&v110=39/v125>0:P36/v125; */ Iona - Genies
!!FU1&v110=34/v125>0:P32/v125; */ Josephine - Stone Golems
!!FU1&v110=32/v125>0:P30/v125; */ Piquedram - Stone Gargoyles
!!FU1&v110=33/v125>0:P36/v125; */ Thane - Genies
*/ Wizard- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=44/v125>0:P34/v125; */ Theodorus - Magi
*/ Demoniac- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=53/v125>0:P44/v125; */ Calh - Gogs
!!FU1&v110=48/v125>0:P46/v125; */ Fiona - Hell Hounds
!!FU1&v110=51/v125>0:P42/v125; */ Ignatius - Imps
!!FU1&v110=50/v125>0:P48/v125; */ Marius - Demons
!!FU1&v110=55/v125>0:P50/v125; */ Nymus - Pit Fiends
!!FU1&v110=49/v125>0:P52/v125; */ Rashka - Efreet
!!FU1&v110=155/v125>0:P54/v125; */ Xeron - Devils (1 mercury)
*/ Death Knight- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=67/v125>0:P60/v125; */ Charna - Wights
!!FU1&v110=71/v125>0:P56/v125; */ Galthran - Skeletons
!!FU1&v110=150/v125>0:P66/v125; */ Lord Haart - Black Knights
!!FU1&v110=66/v125>0:P64/v125; */ Moandor - Liches
!!FU1&v110=64/v125>0:P58/v125; */ Straker - Walking Dead
!!FU1&v110=68/v125>0:P66/v125; */ Tamika - Black Knights
!!FU1&v110=65/v125>0:P62/v125; */ Vokial - Vampires
*/ Overlord- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=83/v125>0:P74/v125; */ Ajit - Beholders
!!FU1&v110=82/v125>0:P78/v125; */ Dace - Minotaurs
!!FU1&v110=80/v125>0:P72/v125; */ Lorelei - Harpies
!!FU1&v110=151/v125>0:P82/v125; */ Mutare - Red Dragons (1 sulfur)
!!FU1&v110=153/v125>0:P82/v125; */ Mutare Drake - Red Dragons (1 sulfur)
!!FU1&v110=87/v125>0:P70/v125; */ Shakti - Troglodytes
!!FU1&v110=86/v125>0:P80/v125; */ Synca - Manticores
*/ Barbarian - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=154/v125>0:P90/v125; */ Boragus - Ogres
!!FU1&v110=100/v125>0:P84/v125; */ Gretchin - Goblins
!!FU1&v110=98/v125>0:P88/v125; */ Jabarkas - Orcs
!!FU1&v110=149/v125>0:P96/v125; */ Kilgor - Behemoths
!!FU1&v110=101/v125>0:P90/v125; */ Krellion - Ogres
!!FU1&v110=99/v125>0:P92/v125; */ Shiva - Rocs
!!FU1&v110=103/v125>0:P86/v125; */ Tyraxor - Wolf Riders
!!FU1&v110=96/v125>0:P94/v125; */ Yog - Cyclopes
*/ Battle Mage - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=105/v125>0:P90/v125; */ Vey - Ogres
*/ Beastmaster - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=116/v125>0:P102/v125; */ Alkin - Gorgons
!!FU1&v110=119/v125>0:P108/v125; */ Broghild - Wyverns
!!FU1&v110=112/v125>0:P106/v125; */ Bron - Basilisks
!!FU1&v110=113/v125>0:P98/v125; */ Drakon - Gnolls
!!FU1&v110=117/v125>0:P104/v125; */ Korbac - Serpent Flies
!!FU1&v110=114/v125>0:P100/v125; */ Wystan - Lizardmen
*/ Planeswalker- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!!FU1&v110=133/v125>0:P113/v125; */ Erdamon - Earth Ele.
!!FU1&v110=134/v125>0:P114/v125; */ Fiur - Fire Ele.
!!FU1&v110=130/v125>0:P114/v125; */ Ignissa - Fire Ele.
!!FU1&v110=135/v125>0:P115/v125; */ Kalt - Water Ele.
!!FU1&v110=131/v125>0:P115/v125; */ Lacus - Water Ele.
!!FU1&v110=132/v125>0:P120/v125; */ Monere - Psychic Ele.
!!FU1&v110=128/v125>0:P120/v125; */ Pasis - Psychic Ele.
!!FU1&v110=129/v125>0:P113/v125; */ Thunar - Earth Ele.
********************************************************************************
!?FU1;
*/ Calculate the amount of gold/mercury/sulfur the upgrade will cost
*/
*/ x1 = Hero's monster speciality picture
*/ x2 = Total of Peasants
*/
*/ y1 = Amount of gold of the owner
*/ y2 = Upgrade cost
*/ y3 = Amount of money the Peasant would have cost (substract to y2)
*/ y4 = Amount of gold the creature cost
*/ y5 = Amount of mercury the creature cost
*/ y6 = Amount of mercury of the owner
*/ y7 = Amount of sulfur the creature cost
*/ y8 = Amount of sulfur of the owner
*/ y9 = Cost of Peasant
*/ y10 = Total of Mercury/Sulfur for the upgrade

!!IF:V125/0;
!!IF:Q130/21/x1/2^Would you like to train your Peasants into^;

*/ Get the total amount of gold/mercury/sulfur of the owner and the speciality creature
!!OW&130:R-1/6/?y1 R-1/1/?y6 R-1/3/?y8;
!!MA&130:Cx1/6/?y4 Cx1/1/?y5 Cx1/3/?y7 C139/6/?y9;

*/ Calculate the amount of mercury/sulfur it will cost
!!VRy10&130/y5>0/y7=0:Sx2 *y5;
!!IF&130/y5>0/y7=0:V128/1 V129/0;
!!VRy10&130/y5=0/y7>0:Sx2 *y7;
!!IF&130/y5=0/y7>0:V128/0 V129/1;
!!VRy10&130/y5=0/y7=0:Sx2 *0;
!!IF&130/y5=0/y7=0:V128/0 V129/0;

*/ Calculate the amount of gold it will cost
!!VRy2&130:Sx2 *y4;
!!VRy3&130:Sx2 *y9;
!!VRy2&130:-y3;

*/ If something's wrong
!!IF&130/y1<y2:V125/0 V130/0 M^Sorry, but you don't have enough gold.^;
!!IF&130/128/y6<y10:V125/0 V130/0 M^Sorry, but you don't have enough mercury.^;
!!IF&130/129/y8<y10:V125/0 V130/0 M^Sorry, but you don't have enough sulfur.^;

*/ If everything's right
!!IF&130/-128/-129/y1>y2:V125/1 M^Upgrade cost : %Y2 gold.^;
!!IF&130/128/y6>y10:V125/1 M^Upgrade cost : %Y2 gold
and %Y10 mercury.^;
!!IF&130/129/y8>y10:V125/1 M^Upgrade cost : %Y2 gold
and %Y10 sulfur.^;

!!FU2&125:Py1/y2/x1/y5/y6/y7/y8/y10;
********************************************************************************
!?FU2;
*/ Substract the amount of gold/mercury/sulfur the upgrade have cost and change
*/ the Peasants into the respective creature
*/
*/ x1 = Amount of gold of the player
*/ x2 = Cost of the upgrade
*/ x3 = Hero's monster speciality number
*/ x4 = Mercury the creature cost
*/ x5 = Mercury of the owner
*/ x6 = Sulfur the creature cost
*/ x7 = Sulfur of the owner
*/ x8 = Total of Mercury/Sulfur for the upgrade
*/
*/ y11 - y24 = Get the type and number of creatures in each of the 7 slots on the hero

*/ Substract the gold
!!VRx1:-x2;
!!OW:R-1/6/x1;

*/ Substract the mercury
!!VRx5&128:-x8;
!!OW&128:R-1/1/x5;

*/ Substract the sulfur
!!VRx7&129:-x8;
!!OW&129:R-1/3/x7;

*/ Change Peasants that lies in any slots into the speciality creature
!!HE-1:C0/0/?y11/?y12 C0/1/?y13/?y14 C0/2/?y15/?y16 C0/3/?y17/?y18 C0/4/?y19/?y20 C0/5/?y21/?y22 C0/6/?y23/?y24;
!!HE-1&y11=139:C0/0/x3/y12; */ Slot 1
!!HE-1&y13=139:C0/1/x3/y14; */ Slot 2
!!HE-1&y15=139:C0/2/x3/y16; */ Slot 3
!!HE-1&y17=139:C0/3/x3/y18; */ Slot 4
!!HE-1&y19=139:C0/4/x3/y20; */ Slot 5
!!HE-1&y21=139:C0/5/x3/y22; */ Slot 6
!!HE-1&y23=139:C0/6/x3/y24; */ Slot 7

------------------------------------------------------------------
6.script-upgraded hill fort v1.2


ZVSE
AUTO_PoweredBy=ERM Script Editor v.1.2.6.32
*/ Upgraded Hill Fort ERM script v1.1 --- wolfmah
*/ Requires WOG 3.55 or later
*/
*/ This script will allow you to any any creatures that have a new WoG
*/ counterparts. This mean, all level 7 upgrade can be upgrade into level 8,
*/ Zealots into War Zealots, Sharpshooters into Artic or Lava Sharpshooters
*/ and so on.
*/
*/ Object use : (map editor) 4th row - 3rd column in the Town section
*/
*/ To use this script, copy and paste it in a global event on a map, set it to
*/ never happen (minimum of 600 day) and uncheck all colours.
*/
*/ Variable and Function that CAN be re-used elsewhere :
*/ Q110 - 111 - 113 - 115 - 117 - 119 - 121 - 123
*/ v111 - 112 - 113 - 114 - 115 - 116 - 117 - 118 - 119 - 120 - 121 -
*/ 122 - 123 - 124
*/ FU400 - 401 - 402
*/
*/ Variable and Function that CANNOT be re-used elsewhere :
*/ z405

*/ Set up hint text for "Upgraded Hill Fort" objects
!#VRz405:S^Upgraded Hill Fort^;
!#HT63/4:T400;

!?OB63/4; */ Triggers when any Upgraded Hill Fort is visited

*/ Will be use to know if the hero got at least 1 creature that can be upgrade
!!IF:V111/0;
!!IF:V113/0;
!!IF:V115/0;
!!IF:V117/0;
!!IF:V119/0;
!!IF:V121/0;
!!IF:V123/0;

*/ Check monster
!!HE-1:C0/0/?v111/?v112; */ Slot 1
!!HE-1:C0/1/?v113/?v114; */ Slot 2
!!HE-1:C0/2/?v115/?v116; */ Slot 3
!!HE-1:C0/3/?v117/?v118; */ Slot 4
!!HE-1:C0/4/?v119/?v120; */ Slot 5
!!HE-1:C0/5/?v121/?v122; */ Slot 6
!!HE-1:C0/6/?v123/?v124; */ Slot 7

*/ Check if the type of monster is ok
!!FU400:Pv111/0;
!!FU400:Pv113/1;
!!FU400:Pv115/2;
!!FU400:Pv117/3;
!!FU400:Pv119/4;
!!FU400:Pv121/5;
!!FU400:Pv123/6;

*/ remove monster who are not allowed
!!HE-1&-111:C0/0/0/0;
!!HE-1&-113:C0/1/0/0;
!!HE-1&-115:C0/2/0/0;
!!HE-1&-117:C0/3/0/0;
!!HE-1&-119:C0/4/0/0;
!!HE-1&-121:C0/5/0/0;
!!HE-1&-123:C0/6/0/0;

!!HE-1&1000:D;

*/ replace monster that were remove
!!HE-1&-111:C0/0/v111/v112;
!!HE-1&-113:C0/1/v113/v114;
!!HE-1&-115:C0/2/v115/v116;
!!HE-1&-117:C0/3/v117/v118;
!!HE-1&-119:C0/4/v119/v120;
!!HE-1&-121:C0/5/v121/v122;
!!HE-1&-123:C0/6/v123/v124;

!!FU402:P;
********************************************************************************
!?FU400;
*/ Check if the type of monster is ok
*/ x1 : Type of monster
*/ x2 : Slot of the monster
!!IF:V110/0;

!!IF&x1=8:V110/1; */ Monk
!!IF&x1=9:V110/1; */ Zealot
*/ Monk - Zealot | War Zealot
!!FU401|x1=8/x1=9:Px1/169;

!!IF&x1=12:V110/1; */ Angel
!!IF&x1=13:V110/1; */ Archangel
*/ Angel - Archangel | Supreme Archangel
!!FU401|x1=12/x1=13:Px1/150;

!!IF&x1=24:V110/1; */ Unicorn
!!IF&x1=25:V110/1; */ War Unicorn
*/ Unicorn - War Unicorn | Nightmare
!!FU401|x1=24/x1=25:Px1/172;

!!IF&x1=26:V110/1; */ Green Dragon
!!IF&x1=27:V110/1; */ Gold Dragon
*/ Green Dragon - Gold Dragon | Diamond Dragon
!!FU401|x1=26/x1=27:Px1/151;

!!IF&x1=28:V110/1; */ Gremlin
!!IF&x1=29:V110/1; */ Master Gremlin
*/ Gremlin - Master Gremlin | Santa Gremlin
!!FU401|x1=28/x1=29:Px1/173;

!!IF&x1=40:V110/1; */ Giant
!!IF&x1=41:V110/1; */ Titan
*/ Giant - Titan | Lord of Thunder
!!FU401|x1=40/x1=41:Px1/152;

!!IF&x1=54:V110/1; */ Devil
!!IF&x1=55:V110/1; */ Arch Devil
*/ Devil - Arch Devil | Antichrist
!!FU401|x1=54/x1=55:Px1/153;

!!IF&x1=68:V110/1; */ Bone Dragon
!!IF&x1=69:V110/1; */ Ghost Dragon
*/ Bone Dragon - Ghost Dragon | Blood Dragon
!!FU401|x1=68/x1=69:Px1/154;

!!IF&x1=82:V110/1; */ Red Dragon
!!IF&x1=83:V110/1; */ Black Dragon
*/ Red Dragon - Black Dragon | Darkness Dragon
!!FU401|x1=82/x1=83:Px1/155;

!!IF&x1=96:V110/1; */ Behemoth
!!IF&x1=97:V110/1; */ Ancient Behemoth
*/ Behemoth - Ancient Behemoth | Ghost Behemoth
!!FU401|x1=96/x1=97:Px1/156;

!!IF&x1=110:V110/1; */ Hydra
!!IF&x1=111:V110/1; */ Chaos Hydra
*/ Hydra - Chaos Hydra | Hell Hydra
!!FU401|x1=110/x1=111:Px1/157;

!!IF&x1=130:V110/1; */ Firebird
!!IF&x1=131:V110/1; */ Phoenix
*/ Firebird - Phoenix | Sacred Phoenix
!!FU401|x1=130/x1=131:Px1/158;

!!IF&x1=137:V110/1; */ Sharpshooter
*/ Sharpshooter - Artic Sharpshooter
!!FU401&x1=137:Px1/170;
*/ Artic Sharpshooter - Lava Sharpshooter
!!FU401&x1=137:P170/171;
*/ Lava Sharpshooter - Artic Sharpshooter
!!FU401&x1=137:P171/170;

!!IF&110/x2=0:V111/1;
!!IF&110/x2=1:V113/1;
!!IF&110/x2=2:V115/1;
!!IF&110/x2=3:V117/1;
!!IF&110/x2=4:V119/1;
!!IF&110/x2=5:V121/1;
!!IF&110/x2=6:V123/1;
********************************************************************************
*/ x1 : monster type
*/ x2 : monster type to upgrade to
!?FU401;

!!MA:Ux1/x2;
********************************************************************************
!?FU402;

!!FU401:P8/-1;
!!FU401:P9/-2;
!!FU401:P12/-1;
!!FU401:P13/-2;
!!FU401:P24/-1;
!!FU401:P25/-2;
!!FU401:P26/-1;
!!FU401:P27/-2;
!!FU401:P28/-1;
!!FU401:P29/-2;
!!FU401:P40/-1;
!!FU401:P41/-2;
!!FU401:P54/-1;
!!FU401:P55/-2;
!!FU401:P68/-1;
!!FU401:P69/-2;
!!FU401:P82/-1;
!!FU401:P83/-2;
!!FU401:P96/-1;
!!FU401:P97/-2;
!!FU401:P110/-1;
!!FU401:P111/-2;
!!FU401:P130/-1;
!!FU401:P131/-2;
!!FU401:P137/-2;
!!FU401:P170/-2;
!!FU401:P171/-2;
********************************************************************************

Remélem áttekinthetőek.
Direkt el választottam őket a kis csikokkal egymástól hogy áttekinthetőbbek legyenek.

_________________
Thrilmalia - Cseho - Ragnaros EU


A hozzászólást 4 alkalommal szerkesztették, utoljára Cseho 2003 szept. 04 csüt., 20:08-kor.

Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 04 csüt., 19:30 
Avatar
&nbsp;
&nbsp;

Csatlakozott: 2003 ápr. 10 csüt., 20:59
Hozzászólások: 136
Tartózkodási hely: Budapest
Elküldöm azokat a bizonyos szkripteket amiket írtam. Most pillanatnyilag
nekem nincs fent a WOG, és éppen vizsgára készülök, ezért csak emlékezetből
fogom leírni, hogy az egyes scriptek mire jók.

[witch hut check]

Amikor bemész a hőssel egy WICH HUT-ba, akkor meg fogja kérdezni, hogy
biztosan meg akarod-e tanulni a tartalmát. Timothy Pulver, a WOG egyik
készítője küldött nekem anno egy függvényt(!?FU5014), ami elvileg átállítja
az adott WITCH HUT control word-jét, és így átmegy amaz VISITED státuszba:
látni fogjuk, hogy mit tartalmaz.

[Upgrade Specialist]
Egy kis példa, hogyan állítsuk át egy adott azonosítójú hősnek a
specialitását. Jelen esetben ORRIN specialitása az 1. és 2. szintű lények
upgradelése lesz.

[logistic]

Mivel enyhén cheater beállítottságú ember(szerű) vagyok, ezért írtam egy
scriptet, amely a megadott hősnek logistic specialitást ad. Lényege: lehet
mellette egy másik specialitásod. Azért kellett hozzá scriptet írni, mert ha
adsz valakinek egy új specialitást, akkor a default elvész. Mivel az elején
egy változóba kell beállítani a !#VRv13:S0; parancsnál a hős ID-t(itt ORRIN
ID-jét állítom be), és a skript folyamán sokszor szükség van erre az
értékre, elég itt beállítani, mert a többi sorban már a változóra
hivatkozok.
A !#TM1:S1/500/1/1; parancsnál be kell állítanunk azt is, hogy melyik
játékosra működjön a dolog, tehát szükségünk lesz az ERM help-re a
bealításhoz.
Sajnos a szkript több WOG-os szkripttel összeakadt, a végén tesztelésképpen
kiíratom ezért a lépések számát.

[upgraded external creature dwellings]

A külső termőhelyeken upgradelt lényeket lehet kapni ,de sajna a CONFLUX
lények ID-je nincs megfelelően számozva, így ott nem üzemel.

[haste speciality]
Ha jól emlékszem akkor az Ivor(21-ed ID?) névre hallgató hősnek csata
kezdetén, minden lénye haste varázslatot kap

[expert town portal]

Szerettem volna, ha a town portal experten funkcionál, mágiától függetlenül,
tehát ideiglenesen a varázslat használatakor kap a hősünk egy expert eart
magic-et.
Sajnos ez sem úgy működik, ahogy kellene.


Én még a 3.56-os WOG-ban írtam a sripteket, és valamelyik bonyolultabb, mint
ahogy meg lehetett volna csinálni, de sajnos egy két funkció nem működött(és
lehet, hogy még a 3.57f-ben sem)

Próbáltam gyorsan és tömören leírni a dolgokat, de azt hiszem ráfér egy-két
teszt a szkriptjeimre. Ha valamit rosszul írtam vagy hiányosan, akkor
elnézést kérek, de hát sajnos sokat felejtettem 1 év alatt. Megjegyzem az
angol tudásom megközelíti a nagyon alapfokot, de el nem éri, és így a help
használatához is sűrűn "elővettem" a haveromat, de sajna már elég ritkán
találkozok vele, így ha az WOG oldallal kapcsolatban kérdeztek valamit,
akkor nem biztos, hogy tudok segíteni :(

[OBJ típus]
ZVSE
AUTO_PoweredBy=ERM Script Editor v.1.2.6.21h
!?OB7/7/0;
!!OB7/7/0:T?v1;
!!IF:M^Variable v=%V1.^;

[witch hut check]
used variables: v1-v5
ZVSE
!?OB113&1000;
!!HE-1:P?v1/?v2/?v3;
!!WHv1/v2/v3:S?v4;
!!HE-1:Sv4/?v5;
!!OBv1/v2/v3:S;
!!VRv4:Sv4*3+3;
!!IF&v5=0:Q1/20/v4/2^Meg akarod tanulni? ^;
!!IF&v5>0:V1/1;
!?OB113&1;
!!OBv1/v2/v3:R;
!?OB113&-1;
!!HE-1:P?v2/?v3/?v4;
!!FU5014:Pv2/v3/v4;

!?FU5014;
[Get current player - store in y1]
!!OW:C?y1;
[Convert player number into bit value for control word (y1)]
!!VRy1:+1*32;
[Set control word so that active player has 'visited' witch hut]
!!OBx1/x2/x3:C?x4;
!!VRx4:|y1;
!!OBx1/x2/x3:Cx4;


[Upgrade Specialist]
ZVSE
!?CM:I2001;
!!HE0:D;

[logistic]
ZVSE
used variables: v2-v13
used flags: 2-5
!#VRv13:S0; itt állítjuk be a hős ID-t
!#TM1:S1/500/1/1;
!?TM1&-1;
!!VRv2:C0/0/0/0/0/0/0/0/0/0/0/0/0;
!!HEv13:S2/?v2; logistic lekérdezés
!!IF&v2=0:V5/1;flag5-none
!!IF&v2=1:V2/1; flag2-basic
!!IF&v2=2:V3/1; flag3-adv
!!IF&v2=3:V4/1; flag4*exp
!!HEv13:A1/?v3/6; jobb gyűrű -ha v3 70 akkor kesztyű 15
!!HEv13:A1/?v4/7; bal gyűrű ha v4 70 akkor kesztyű 15
!!HEv13:A1/?v5/8; láb ha v5 98 akkor cipő 98
!!HEv13:W?v6; movement
!!VRv7&5:S0;none log levonás
!!VRv7&2:S10; basic log levonás
!!VRv7&3:S20; adv log levonás
!!VRv7&4:S30; exp log levonás
!!VRv8&v3=70:S15; kesztyű
!!VRv8&v4=70:S15; kesztyű
!!VRv9&v5=98:S30; cipő
!!HEv13:E?v11/?v10; szint lekérdezése v10be
!!VRv11:Sv7+v8+v9+100; összes módosító
!!VRv12:Sv6*100:v11;
!!VRv12:Sv12:20*v10; bonus log;
!!VRv6:Sv6+v12; végeredmény;
!!HEv13:Wv6; beállítás
!!IF:M^Variable i=%V6.^;
The End



[upgraded external creature dwellings]
ZVSE

!?OB17;
!!HE-1:P?v10/?v11/?v12;
!!DWv10/v11/v12:M0/?v2/?v3;
!!VRv4&v2<112:Sv2%2;
!!VRv2&v4=0/v2<112:Sv2+1;
!!DWv10/v11/v12:M0/v2/?v3;

[haste speciality]
ZVSE

!?FU1;
!!BMv2:M53/50/3;
!!VRv2:Sv2+1;

!?BF;
!!BA:H0/?v3;
!!BA:H1/?v4;
!!VRv2&v4=2:S21;
!!DO1/0/20/1&v3=2:P1;
!!DO1/0/20/1&v4=2:P1;
!!VRv3:S0;
!!VRv4:S0;
!!VRv2:S0;

[expert town portal]
ZVSE
!?GE1;
!!HE2:S17/?w99;
!?BF;
!!HE2:S17/w99;
!?HM-1;
!!HE2:S17/w99;
!?CM:I8;
!!HE2:S17/?v99;
!!HE2&v99<3:S17/?w99;
!!HE2:S17/3;


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 04 csüt., 19:37 
Avatar
Heroes Team

Csatlakozott: 2003 márc. 25 kedd, 11:16
Hozzászólások: 205
Skacok, majd tiltsátok le az Emotikonokat, ha ide vágjátok be a forrást, mert a :) ill. :P, stb... jelekből kicsisárgafejet varázsol a fórum...
(A korábbi üzeneteitekben átállítottam, majd csak az újakra kell odafigyelni.)

Amúgy le a kalappal, ha ti ezt értitek :)


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 04 csüt., 19:47 
Avatar
a verbális armageddon

Csatlakozott: 2003 júl. 22 kedd, 18:23
Hozzászólások: 485
Tartózkodási hely: Komárom
Köszönjuk szépen Menyus és köszi a tippet :!:

_________________
Thrilmalia - Cseho - Ragnaros EU


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 11 csüt., 18:20 
Avatar

Csatlakozott: 2003 júl. 13 vas., 16:10
Hozzászólások: 260
Tartózkodási hely: Szeged
A következő dolgokat Csehonak ajánlom:
Lények statjának megváltoztatása:
!#MA:***;
A *** helyére:
A#1/$ : A #1 számú szörnynek $ defense lesz.
D#1/$ :Ua., csak defense.
M#1/$ :Min. sebzés
E#1/$ :Max sebzés
P#1/$ :Élet
A ghost száma: 159
Tipp: Mindent nagybetűvel írj ennél a scriptnél.


A hozzászólást 1 alkalommal szerkesztették, utoljára Fizban 2005 aug. 25 csüt., 6:44-kor.

Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 11 csüt., 21:00 
Avatar
a verbális armageddon

Csatlakozott: 2003 júl. 22 kedd, 18:23
Hozzászólások: 485
Tartózkodási hely: Komárom
Itt egy újjab script:

Hyper Peasant

Jellemzői:

Attack Skill:100
Defense Skill:50
Damage:50
Health:105
Health Left:105
Speed:40


ZVSE
AUTO_PoweredBy=ERM Script Master v.1.1.2.7

*** Hyper Peasant ***
!#MA: C139/6/10 A139/100 D139/50 P139/105 S139/40 M139/50 E139/50 N139/0 G139/25 B139/0 R139/0 I139/15 F139/15 L139/49 O139/9 X139/16; Peasant
*** END OF SCRIPT ***
* 2003.09.11. 20:40:02 *

És a párja:

Szuper Ballista

ZVSE
AUTO_PoweredBy=ERM Script Master v.1.1.2.7

*** Szuper Ballista ***
!#MA: C146/6/2500 A146/105 D146/60 P146/350 S146/30 M146/100 E146/101 N146/100 G146/10 B146/0 R146/0 I146/600 F146/650 L146/49 O146/9 X146/201797; Ballista
*** END OF SCRIPT ***
* 2003.09.11. 21:08:01 *

Köszönet Fizbannak és Bishopnak :!:

_________________
Thrilmalia - Cseho - Ragnaros EU


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 13 szomb., 23:16 
Avatar
Heroes Team

Csatlakozott: 2003 aug. 28 csüt., 16:32
Hozzászólások: 1563
Tartózkodási hely: alapítottam már egyet :P
HI mindenkinek :!:

Szuper Necropolis

ZVSE
AUTO_PoweredBy=ERM Script Master v.1.1.2.7

*** Necropolis ***
!#MA: C56/6/30 A56/5 D56/4 P56/8 S56/4 M56/3 E56/5 N56/0 G56/12 B56/0 R56/6 I56/60 F56/75 L56/0 O56/4 X56/394240; Skeleton
!#MA: C57/6/40 A57/7 D57/8 P57/9 S57/5 M57/4 E57/5 N57/0 G57/12 B57/0 R57/6 I57/85 F57/85 L57/0 O57/4 X57/427008; Skeleton Warrior
!#MA: C58/6/50 A58/5 D58/5 P58/20 S58/1 M58/4 E58/7 N58/0 G58/8 B58/0 R58/0 I58/98 F58/140 L58/1 O58/4 X58/394240; Walking Dead
!#MA: C59/6/60 A59/5 D59/5 P59/50 S59/2 M59/4 E59/8 N59/0 G59/4 B59/0 R59/0 I59/128 F59/160 L59/1 O59/4 X59/394240; Zombie
!#MA: C60/6/80 A60/7 D60/9 P60/7 S60/5 M60/3 E60/5 N60/0 G60/20 B60/0 R60/0 I60/252 F60/231 L60/2 O60/4 X60/263682; Wight
!#MA: C61/6/100 A61/10 D61/10 P61/15 S61/7 M61/5 E61/7 N61/0 G61/7 B61/0 R61/0 I61/315 F61/252 L61/2 O61/4 X61/263682; Wraith
!#MA: C62/6/260 A62/13 D62/14 P62/35 S62/6 M62/7 E62/10 N62/0 G62/4 B62/0 R62/0 I62/555 F62/518 L62/3 O62/4 X62/394242; Vampire
!#MA: C63/6/300 A63/16 D63/14 P63/42 S63/9 M63/8 E63/11 N63/0 G63/4 B63/0 R63/0 I63/783 F63/652 L63/3 O63/4 X63/394242; Vampire Lord
!#MA: C64/6/450 A64/15 D64/12 P64/40 S64/6 M64/13 E64/15 N64/12 G64/3 B64/0 R64/0 I64/848 F64/742 L64/4 O64/4 X64/1442820; Lich
!#MA: C65/6/500 A65/18 D65/13 P65/45 S65/7 M65/13 E65/17 N65/24 G65/3 B65/0 R65/0 I65/1079 F65/889 L65/4 O65/4 X65/1475588; Power Lich
!#MA: C66/6/1000 A66/20 D66/20 P66/150 S66/7 M66/20 E66/32 N66/0 G66/2 B66/0 R66/0 I66/2087 F66/1753 L66/5 O66/4 X66/394241; Black Knight
!#MA: C67/6/1200 C67/2/2 A67/25 D67/25 P67/200 S67/9 M67/30 E67/35 N67/0 G67/2 B67/0 R67/0 I67/2382 F67/2029 L67/5 O67/4 X67/427009; Dread Knight
!#MA: C68/6/1500 A68/25 D68/20 P68/200 S68/9 M68/35 E68/60 N68/0 G68/1 B68/0 R68/0 I68/3388 F68/2420 L68/6 O68/4 X68/394371; Bone Dragon
!#MA: C69/6/2000 C69/1/1 A69/40 D69/38 P69/300 S69/14 M69/35 E69/60 N69/0 G69/1 B69/0 R69/0 I69/4696 F69/3228 L69/6 O69/4 X69/394371; Ghost Dragon
*** END OF SCRIPT ***
* 2003.09.13. 14:31:33 *

Elnézést, de probléma volt a Wightel és a Wraithtal.

Köszönöm Csehonak a segítséget:!:

_________________
Üdv!
KTibsza


A hozzászólást 2 alkalommal szerkesztették, utoljára KTibsza 2003 szept. 15 hétf., 19:19-kor.

Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 14 vas., 17:54 
Avatar
a verbális armageddon

Csatlakozott: 2003 júl. 22 kedd, 18:23
Hozzászólások: 485
Tartózkodási hely: Komárom
Tibsza az igazi érdem mégsem az enyim hanem Bishopé és Fizbané :D
Ők mutatták meg nekem az oldalt :D
Azért az nem semmi ahogy át írtad az egész Necropolist :D
Na irány kiprobálni :D

_________________
Thrilmalia - Cseho - Ragnaros EU


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 14 vas., 18:31 
Avatar
a verbális armageddon

Csatlakozott: 2003 júl. 22 kedd, 18:23
Hozzászólások: 485
Tartózkodási hely: Komárom
Super Marksman

Az ára 1 arany és a basic growja 30 :D

ZVSE
AUTO_PoweredBy=ERM Script Master v.1.1.2.7

*** Castle-Super Marksman ***
!#MA: C3/6/1 A3/70 D3/40 P3/160 S3/30 M3/70 E3/71 N3/70 G3/30 B3/0 R3/0 I3/300 F3/200 L3/1 O3/0 X3/32788; Marksman
*** END OF SCRIPT ***
* 2003.09.13. 13:35:03 *

A párja:
Erősített Arrow Tower

*** Arrow Tower ***
!#MA: C149/6/1000 A149/100 D149/45 P149/200 S149/0 M149/100 E149/130 N149/99 G149/0 B149/0 R149/0 I149/400 F149/5 L149/99 O149/9 X149/132164; Arrow Tower
*** END OF SCRIPT ***
* 2003.09.13. 13:40:07 *

A kettő scripttel együtt egész jó kis vár védelmet össze lehet dobni :D

_________________
Thrilmalia - Cseho - Ragnaros EU


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 14 vas., 18:37 
Avatar
a verbális armageddon

Csatlakozott: 2003 júl. 22 kedd, 18:23
Hozzászólások: 485
Tartózkodási hely: Komárom
Ez egy érdekes script.

Ezzel a scripttel mi válogathatjuk össze hogy milyen lényeket vehessünk a várunkban.
1.nap 1. szintű
2.nap 2.szintű
stb.. egészen a hetedik napig
Elég hasznos egy script !
Ezzel meg lehet valósítani KTbisza vegyes csapatait!

Choose Creature Types and Build Dwellings

ZVSE

[Timer 11 for choosing creature types in first week]
!#TM11:S1/7/1/255;

[Set up tables of creature types for each level]
!#VRv101:C0/14/28/42/56/70/84/98/118/143; [Level 1]
!#VRv111:C2/16/30/44/58/72/86/100/112/140; [Level 2]
!#VRv121:C4/18/32/46/60/74/88/104/115/141; [Level 3]
!#VRv131:C6/20/34/48/62/76/90/106/114/144; [Level 4]
!#VRv141:C8/22/36/50/64/78/92/102/113/117; [Level 5]
!#VRv151:C10/24/38/52/66/80/94/108/120/136; [Level 6]
!#VRv161:C12/26/40/54/68/82/96/110/130/168; [Level 7]

[Make Rogues level 1, Trolls level 4, and Diamond Golems level 5]
[Adjust growth rates: Rogues: 10, Trolls: 4, Diamond Golems: 3]
!#MA:L143/0 L144/3 L117/4 G143/10 G144/4 G117/3;

---------------------------------------------------------------------------------------------

[Choose creature types]
!?TM11;
!!VRv1:Sc; [Current Day: v1]
!!FU58&v1=1:P; [Set up Garrison Towns on first day]
!!FU4:P; [Choose creature types]

---------------------------------------------------------------------------------------------

[Choose creature types]
!?FU4;

!!VRy1:Sc0; [Creature Level: y1 (Level=day of week)]
!!OW:C?y2; [Current player #: y2 (0-7)]

[Check town type of this player: y3]
!!CA23/51/1&y2=0:T?y3;
!!CA67/40/1&y2=1:T?y3;
!!CA31/26/1&y2=3:T?y3;
!!CA13/4/1&y2=4:T?y3;

!!CA23/51/1&y3=2/y1=1:B1/22; [Build Library in Tower]
!!CA65/67/1&y3=3/y1=1:B1/22; [Build Castle Gate in Inferno Garrison]
!!CA13/4/1&y3=4/y1=1:B5/22; [Disable Skelly Transformer in Necropolis]
!!CA13/4/1&y3=4/y1=1:B1/18; [Build Unearthed Graves in Necropolis]
!!CA31/26/1&y3=8/y1=1:B1/21; [Build Magic University in Conflux]

!!VRz10:S^%Gc Player, choose your level %Y1 Creature Type.^;

[Fill z variables with creature type for each option]
!!DO5/11/20/1:Py1;

[Dialogue Box: 1=checkboxes, 11=v11 receives result]
[0=all check boxes off to start, 1=z1 stores header]
[11..19=z11-z20 store creature names]
[z130 - random creature option]
!!VRz130:S^Random Level %Y1 Creature^;
!!VRv1:S0; [Initialize v1 to 0]
!!IF&1000:G1/1/0/10/11/12/13/14/15/16/17/18/19/20/130;

[Determine creature number chosen: y5]
!!VRy5&v1=1:Sy1*10 +90 +1;
!!VRy5&v1=2:Sy1*10 +90 +2;
!!VRy5&v1=4:Sy1*10 +90 +3;
!!VRy5&v1=8:Sy1*10 +90 +4;
!!VRy5&v1=16:Sy1*10 +90 +5;
!!VRy5&v1=32:Sy1*10 +90 +6;
!!VRy5&v1=64:Sy1*10 +90 +7;
!!VRy5&v1=128:Sy1*10 +90 +8;
!!VRy5&v1=256:Sy1*10 +90 +9;
!!VRy5&v1=512:Sy1*10 +90 +10;
!!VRy5&v1=1024:Sy1*10 +91 R9; [Random Choice]
!!VRy5&-1000:Sy1*10 +91 R9; [If AI, choose randomly]
!!VRy5:Svy5; [Creature number: y5]
!!VRy6:Sy5 +1; [Upgraded creature number: y6]
!!VRy6&y5=112:S127; [Storm Elemental]
!!VRy6&y5=113:S125; [Magma Elemental]
!!VRy6&y5=114:S129; [Energy Elemental]
!!VRy6&y5=115:S123; [Ice Elemental]
!!VRy6&y5=143:S143; [Rogue]
!!VRy6&y5=140:S140; [Boar]
!!VRy6&y5=141:S141; [Mummy]
!!VRy6&y5=144:S144; [Troll]
!!VRy6&y5=117:S117; [Diamond Golem]
!!VRy6&y5=136:S136; [Enchanter]
!!VRy6&y5=168:S168; [Gorynych]
!!VRy7:Sy1 -1; [Dwelling level (0-6)]
!!VRy9:Sy7 +30; [Dwelling building number in town]

[Set creature's town type to neutral for morale purposes, etc.]
!!MA:Oy5/-1 Oy6/-1;

[Set creature generator in town to produce this type of creature]
!!UN:Ty3/y7/0/y5 Ty3/y7/1/y6;
!!MA:Gy5/?y8; [Growth rate: y8]

[Set creature to upgrade correctly]
!!MA:Uy5/y6;
!!MA&y5=y6:Uy5/-1; [No upgrades for neutral creatures]

[Build dwellings and set initial correct # of creatures of chosen type]
[Garrison towns get level 1-4 creatures only and no upgrades]
[Garrison towns start with no creatures in the first week]
!!CA23/51/1&y2=0:B1/y9 M1/y7/y8/0; [Red's main castle]
!!CA65/67/1&y2=0/y7<4:B1/y9 M1/y7/0/0; [Red's garrison]
!!CA67/40/1&y2=1:B1/y9 M1/y7/y8/0; [Blue's main castle]
!!CA37/43/1&y2=1/y7<4:B1/y9 M1/y7/0/0; [Blue's garrison]
!!CA31/26/1&y2=3:B1/y9 M1/y7/y8/0; [Green's main castle]
!!CA1/10/1&y2=3/y7<4:B1/y9 M1/y7/0/0; [Green's garrison]
!!CA13/4/1&y2=4:B1/y9 M1/y7/y8/0; [Orange's main castle]
!!CA47/6/1&y2=4/y7<4:B1/y9 M1/y7/0/0; [Orange's garrison]

[Look up Dwelling Name: z2]
!!UN:N2/2/y3/y9;

[Calculate message display picture of dwelling: type=y10, subtype=y9]
!!VRy10:S22 +y3;

[Look up creature name of y5 (plural): z3]
!!UN:N3/3/y5/1;

[Set "a" or "an" depending on dwelling type (y9) in town type (y3): z4]
!!VRz4:S^a^;
!!VRz4&y3=0/y9=31:S^an^; [Archers' Tower]
!!VRz4&y3=0/y9=35:S^^; [Training Grounds]
!!VRz4&y3=3/y9=30:S^an^; [Imp Crucible]
!!VRz4&y3=3/y9=32:S^^; [Kennels]
!!VRz4&y3=4/y9=33:S^an^; [Estate]
!!VRz4&y3=1/y9=30:S^^; [Centaur Stables]
!!VRz4&y3=1/y9=33:S^an^; [Enchanted Spring]
!!VRz4&y3=1/y9=34:S^^; [Dendroid Arches]
!!VRz4&y3=1/y9=36:S^^; [Dragon Cliffs]
!!VRz4&y3=6/y9=32:S^an^; [Orc Tower]
!!VRz4&y3=6/y9=33:S^an^; [Ogre Fort]
!!VRz4&y3=2/y9=34:S^an^; [Altar of Wishes]
!!VRz4&y3=8/y9=31:S^an^; [Altar of Air]
!!VRz4&y3=8/y9=32:S^an^; [Altar of Water]
!!VRz4&y3=8/y9=33:S^an^; [Altar of Fire]
!!VRz4&y3=8/y9=34:S^an^; [Altar of Earth]
!!VRz4&y3=8/y9=35:S^an^; [Altar of Thought]

[Display message]
!!IF&1000:Q3/y10/y9/21/y5/1^{New Town Building}

Lady Celaine has constructed %Z4
%Z2 for your %Z3 to live in.^;

!!FU23:Py1/y2/y5/y8; [Change external dwelling]

---------------------------------------------------------------------------------------------

[Fill z variables z11-z20 with creature type for each option]
[x1=creature level]
!?FU5;

[v variable index for creature number= (x1*10) + 80 + x16]
!!VRy1:Sx1*10 +80 +x16;

[Look up creature name (singular) as vy1]
[z variable index = x16 (z11-z20)]
!!UN:N3/x16/vy1/0;

_________________
Thrilmalia - Cseho - Ragnaros EU


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 16 kedd, 21:07 
Avatar
a verbális armageddon

Csatlakozott: 2003 júl. 22 kedd, 18:23
Hozzászólások: 485
Tartózkodási hely: Komárom
Altar of Transformation

Ez egy olyan script amely át alakitja az egész sereget.
pl:van 5 behemotod és 5 köklopszod,bemész egy házba ahol átalakítja mondjuk 5 titánná és 5 nagává.
Az objektom a 8.sor 3 objektuma.

ZVSE

** Tranformation Altar ERM Script Version 1.2 created by Timothy E. Pulver

** This script lets all "Lightning Altars" on a map function as transformation
** devices. When a hero climbs the altar, his or her army will be transformed
** into different random creatures, while maintaining approximately the same
** level of power. For example, a stack of 10 archers may become a stack of
** 10 dwarves or 10 gargoyles instead. Powerful neutral dragons in the game
** are immune to transformation, as are some of the new WoG creatures.
** Each Transformation Altar on the map can only be visited once per week.

** The "Lightning Altar" is a new WoG object that can be found in the WoG
** Heroes map editor in the Town Objects section. It's the 5th object beneath
** the Conflux castle. It appears as an altar with steps leading up to a pillar
** with a light on top. From the light comes dancing lightning bolts.

** To install this script in a map, simply copy & paste the code into a global
** (timed) event. Copy the entire code, from ZVSE to the end. Make sure
** that you disable ALL colours from receiving the event and/or change
** the event day to something like 500 or later to avoid the ERM script
** popping up as if it were a regular event message. The title of the event
** is unimportant, but I would suggest something like "Transformation Altar".
** And of course, you'll also need to put one or more "Lightning Altars" on
** your map for the heroes to visit. Happy transforming! :-)


Flags Used in this Script: 1,2,77, 209-211
Variables Used in this Script: f,g,i,j,k,l,v88-v90,x16,z75,
Functions Used in this Script: 18001

!?OB63/20; [Triggers when any "Lightning Altar" is visited]

!!IF:V209/0 V210/0 V211/0; [Sets flags 209, 210 and 211 to false]

[Set up right-click hint text for altar object]
!!VRz75:S^Altar of Transformation^;
!!OB998:H75;

[Ask if hero wishes to visit the altar]
!!IF&1000:Q1^Do you climb the steps of the mysterious altar?^;

[If player is AI, generate random response]
!!VRv90&-1000:S0 T1;
!!IF&v90=0/-1000:V1/0;
!!IF&v90=1/-1000:V1/1;

[Check if someone has already visited the altar this week. If noone has and hero visits, set control word to indicate that it has now been visited this week]
!!IF&1:V77/0; [Reset flag 77 to 0]
!!OB998:C?v89; [Get control word of this altar]
!!OB998&v89>999:C0; [If altar hasn't been visited, set its control word to 0]
!!VRv88:Sc0 -1 :7 *7 +1; [Determine most recent Day 1]
!!IF&v88<=v89/1:V77/1; [If most recent Day 1 is earlier or the same as the
the day last visited, don't allow visit]
!!OB998&1:Cc0; [If visiting, set control word to current day]

[If altar has been visited this week, display this message and set flag 1 to false]
!!IF&77/1/1000:M^You climb to the top of the altar but the energy merely sputters around you as if it had recently been drained. Try returning at the beginning of next week.^;
!!IF&77:V1/0;

[If hero visits altar, display this message]
!!IF&1/1000:M^{Flickering Energies}

~~ CRACKLE ~~

{all around you...}^;

[If hero visits altar, set v77 variable to true and make a "teleport hero" sound]
!!IF&1:V77/1;
!!HE-1&1/1000:Pv998/v999/v1000;

[If hero visits altar, perform transformation function 7 times -- once for each army slot]
!!DO18001/0/6/1&1:P;

[After transformation, display this message plus second message if appropriate]
!!IF&1/1000:M^You step down from the altar with
your army transformed!^;
!!IF&209/-211/1000:M^The powerful dragons in your army resist the transformation!^;
!!IF&211/-209/1000:M^The strange new creatures in your army resist the transformation!^;
!!IF&209/211/1000:M^The powerful dragons and the strange new creatures in your army resist the transformation!^;

----------------------------------------------------------------------------------------

[Start of transformation function]
!?FU18001;

!!VRi:S-1; [Sets variable i to -1]
!!HE-1:C0/x16/?i/d0; [Stores value of troop type found in hero's slot x16 in variable i]

!!VRg:S0; [Sets variable g to 0]
!!VRf:S0; [Sets variable f to 0]
!!VRl:S-1; [Sets variable l to -1]
!!IF:V2/0 V210/0; [Sets flag 2 and flag 210 to false]

[If existing troop type is a powerful neutral dragon, set flags 209 and 210 to 1]
!!IF&i>131/i<136:V209/1 V210/1;

!!VRg&i>101/i<104:S4; [If troop type is a gorgon or mighty gorgon, set variable g to 4]
!!VRg&i>103/i<108:S-2; [If troop type is a serpent fly, dragon fly, basilisk or greater basilisk, set variable g to -2]

!!VRi&g<>0:+g; [If variable g does NOT equal 0, add value of g to variable i]
!!IF&g<>0:V2/1; [If variable g does NOT equal 0, set flag 2 to true]

[Sets Conflux plus neutral creatures temporary values that are in numerical order]
!!VRf&i=118:S182; [Pixie]
!!VRf&i=139:S182; [Peasant]
!!VRf&i=119:S183; [Sprite]
!!VRf&i=138:S183; [Halfling]
!!VRf&i=112:S184; [Air Elemental]
!!VRf&i=140:S184; [Boar Rider]
!!VRf&i=127:S185; [Storm Elemental]
!!VRf&i=143:S185; [Rogue]
!!VRf&i=115:S186; [Water Elemental]
!!VRf&i=142:S186; [Nomad]
!!VRf&i=123:S187; [Ice Elemental]
!!VRf&i=141:S187; [Mummy]
!!VRf&i=114:S188; [Fire Elemental]
!!VRf&i=129:S189; [Energy Elemental]
!!VRf&i=116:S189; [Gold Golem]
!!VRf&i=137:S189; [Sharpshooter]
!!VRf&i=113:S190; [Earth Elemental]
!!VRf&i=125:S191; [Magma Elemental]
!!VRf&i=117:S191; [Diamond Golem]
!!VRf&i=144:S191; [Troll]
!!VRf&i=120:S192; [Psychic Elemental]
!!VRf&i=121:S193; [Magic Elemental]
!!VRf&i=136:S193; [Enchanter]
!!VRf&i=130:S194; [Firebird]
!!VRf&i=131:S195; [Phoenix]

!!VRj&i<112:S0 R8; [If troop type is less than 112, set j to random # from 0 to 8]
!!VRj&f>180:S0 R8; [If troop type is greater than 180, set j to random # from 0 to 8]
!!VRj&i<112/j=7/2:S0 R6; [If troop type is less than 112 and j=8 and flag 2 is true, set j to a random # from 0 to 6]
!!VRk&i<112:Si %14; [If troop type is less than 112, set k to the *remainder* of troop type divided by 14]
!!VRk&i>149/i<159:S-1; [If troop type is "Level 8" creature, set k to -1]
!!VRk&i>158/i<180:S-2; [If troop type is another obscure new creature, set k to -2]
!!VRk&f>180:Sf %14; [If troop type is greater than 180, set k to the *remainder* of troop type divided by 14]
!!VRl&k=-1:S150 R8; [If troop type is "Level 8" creature, set l (new troop type) to random new "Level 8" creature]
!!VRl&k=-2:Si; [If troop type is an obscure new creature, just leave it alone]
!!IF&k=-2:V211/1; [If troop type is an obscure new creature, set flag 211 to true]

!!VRl&j=8/k=0:S118; [If j=8 and k=0, set l (new troop type) to Pixie]
!!VRl&j=8/k=1:S119; [If j=8 and k=1, set l (new troop type) to Sprite]
!!VRl&j=8/k=2:S112; [If j=8 and k=2, set l (new troop type) to Air Elemental]
!!VRl&j=8/k=3:S127; [If j=8 and k=3, set l (new troop type) to Storm Elemental]
!!VRl&j=8/k=4:S115; [If j=8 and k=4, set l (new troop type) to Water Elemental]
!!VRl&j=8/k=5:S123; [If j=8 and k=5, set l (new troop type) to Ice Elemental]
!!VRl&j=8/k=6:S114; [If j=8 and k=6, set l (new troop type) to Fire Elemental]
!!VRl&j=8/k=7:S129; [If j=8 and k=7, set l (new troop type) to Energy Elemental]
!!VRl&j=8/k=8:S113; [If j=8 and k=8, set l (new troop type) to Earth Elemental]
!!VRl&j=8/k=9:S125; [If j=8 and k=9, set l (new troop type) to Magma Elemental]
!!VRl&j=8/k=10:S120; [If j=8 and k=10, set l (new troop type) to Psychic Elemental]
!!VRl&j=8/k=11:S121; [If j=8 and k=11, set l (new troop type) to Magic Elemental]
!!VRl&j=8/k=12:S130; [If j=8 and k=12, set l (new troop type) to Firebird]
!!VRl&j=8/k=13:S131; [If j=8 and k=13, set l (new troop type) to Phoenix]

[If troop type is less than 112 or greater than 180 and j does NOT equal 8, set l (new troop type) to: (j x 14) + k ]
!!VRl&i<112/j<>8:Sj *14 +k;
!!VRl&f>180/j<>8:Sj *14 +k;

[Make adjustments to compensate for some of the Fortress creatures being out of order in table]
!!VRg&-2/i<112/l>101/l<106:S2;
!!VRg&-2/i<112/l>105/l<108:S-4;
!!VRg&-2/f>180/l>101/l<106:S2;
!!VRg&-2/f>180/l>105/l<108:S-4;
!!VRl&-2/g<>0:+g;

!!FU18001&i=l/k<>-2:P; [If current troop = new troops, choose another troop]
!!VRi&f>180:Sf; [If f (temporary #) is greater than 180, set current troop type equal to f]

[Set new troop type in slot x16]
!!HE-1&l<>-1/-210:C0/x16/l/d0;

Menyus 1 kérdés:

Lehet Wake of Gods-os mapot küldeni :?:

_________________
Thrilmalia - Cseho - Ragnaros EU


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 16 kedd, 21:15 
Avatar

Csatlakozott: 2003 márc. 29 szomb., 17:19
Hozzászólások: 291
Gyerekek mi ez a sok zagyvaság??


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 16 kedd, 21:19 
Avatar
a verbális armageddon

Csatlakozott: 2003 júl. 22 kedd, 18:23
Hozzászólások: 485
Tartózkodási hely: Komárom
Don hallottál már az In the Wake of Gods-ról :?:
Ez a Heroes3 nem hivatalos kiegészítője.
Ezek a zagyvaságok scriptek,amivel modosításokat lehet végrehajtani a játékon.

_________________
Thrilmalia - Cseho - Ragnaros EU


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 16 kedd, 21:28 
Avatar

Csatlakozott: 2003 márc. 29 szomb., 17:19
Hozzászólások: 291
Persze hogy hallottam róla.5 éves korom óta nyomatom a heroes-t szóval.....Csak az ilyenekhez vagyok hülye.
Én játszani tudok.


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 20 szomb., 19:20 
Avatar

Csatlakozott: 2003 szept. 17 szer., 13:56
Hozzászólások: 37
Tartózkodási hely: komárom
DonJanvari írta:
Persze hogy hallottam róla.5 éves korom óta nyomatom a heroes-t szóval.....Csak az ilyenekhez vagyok hülye.
Én játszani tudok.


Szóval te csak kész pályákkal játszol :D :D :D :D

_________________
Mind örökké In the Wake of Gods és Elemental Conflux és most már a Heroes4 is :D.


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2003 szept. 27 szomb., 20:45 
Avatar
Heroes Team

Csatlakozott: 2003 aug. 28 csüt., 16:32
Hozzászólások: 1563
Tartózkodási hely: alapítottam már egyet :P
Itt van a Super Conflux
Kis erősítések vannak benne, de a magic elem és a főnix már elég jó!

Itt van amit a Time Eventshez kell bemásolni a pályaszerkesztőbe. A napok száma kb. 5-600 legyen.
-----------------------------------------------------------------------------------
ZVSE
AUTO_PoweredBy=ERM Script Master v.1.1.2.7

*** Conflux ***
!#MA: C112/6/200 A112/10 D112/10 P112/30 S112/10 M112/3 E112/5 N112/0 G112/10 B112/0 R112/0 I112/356 F112/324 L112/1 O112/8 X112/132096; Air Elemental
!#MA: C113/6/380 A113/13 D113/15 P113/50 S113/4 M113/5 E113/9 N113/0 G113/5 B113/0 R113/0 I113/330 F113/415 L113/2 O113/8 X113/132096; Earth Elemental
!#MA: C114/6/300 A114/10 D114/7 P114/40 S114/5 M114/5 E114/7 N114/0 G114/6 B114/0 R114/0 I114/345 F114/345 L114/3 O114/8 X114/132096; Fire Elemental
!#MA: C115/6/280 A115/9 D115/8 P115/35 S115/5 M115/4 E115/6 N115/0 G115/8 B115/0 R115/0 I115/315 F115/315 L115/4 O115/8 X115/132097; Water Elemental
!#MA: C118/6/30 A118/5 D118/5 P118/4 S118/8 M118/2 E118/4 N118/0 G118/20 B118/0 R118/10 I118/55 F118/40 L118/0 O118/8 X118/18; Pixie
!#MA: C119/6/35 A119/6 D119/6 P119/5 S119/13 M119/3 E119/4 N119/0 G119/20 B119/0 R119/10 I119/95 F119/70 L119/0 O119/8 X119/65554; Sprite
!#MA: C120/6/600 A120/16 D120/18 P120/80 S120/8 M120/22 E120/22 N120/0 G120/3 B120/0 R120/0 I120/1669 F120/1431 L120/5 O120/8 X120/721920; Psychic Elemental
!#MA: C121/6/800 A121/20 D121/18 P121/100 S121/11 M121/25 E121/25 N121/0 G121/3 B121/0 R121/0 I121/2012 F121/1724 L121/1 O121/8 X121/721920; Magic Elemental
!#MA: C123/6/300 A123/10 D123/9 P123/45 S123/7 M123/5 E123/7 N123/32 G123/8 B123/5 R123/0 I123/380 F123/315 L123/2 O123/8 X123/164869; Ice Elemental
!#MA: C125/6/400 A125/15 D125/15 P125/55 S125/6 M125/6 E125/10 N125/0 G125/5 B125/5 R125/0 I125/490 F125/490 L125/3 O125/8 X125/132096; Magma Elemental
!#MA: C127/6/250 A127/11 D127/10 P127/30 S127/10 M127/4 E127/6 N127/24 G127/10 B127/5 R127/0 I127/486 F127/324 L127/4 O127/8 X127/132100; Storm Elemental
!#MA: C129/6/350 A129/10 D129/9 P129/40 S129/5 M129/4 E129/8 N129/0 G129/6 B129/5 R129/0 I129/470 F129/360 L129/5 O129/8 X129/148480; Energy Elemental
!#MA: C130/6/1000 A130/21 D130/22 P130/250 S130/18 M130/40 E130/50 N130/0 G130/2 B130/0 R130/0 I130/4547 F130/3248 L130/6 O130/8 X130/16539; Firebird
!#MA: C131/6/1500 C131/1/1 A131/25 D131/25 P131/400 S131/21 M131/50 E131/50 N131/0 G131/2 B131/3 R131/0 I131/6721 F131/4929 L131/6 O131/8 X131/16539; Phoenix
*** END OF SCRIPT ***
* 2003.09.27. 15:36:06 *

_________________
Üdv!
KTibsza


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2004 feb. 22 vas., 14:13 
Avatar

Csatlakozott: 2004 feb. 06 pén., 22:43
Hozzászólások: 2256
Tartózkodási hely: TATA
Mik ezek a scriptek és hogy kell őket használni?


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2004 ápr. 11 vas., 22:04 
Avatar

Csatlakozott: 2004 jan. 17 szomb., 1:03
Hozzászólások: 81
Bogpista scriptek azok megváltoztatják a játék egyes tulajdonságait. Olyan mint ha forgatókönyvet írnál . Még a jelentése is ez. Azt, hogy hol használd azt a timed events be lehet megoldani ha jól tudom, én is most kísérletezem rajta de ha jobb és pontosabb infókat akarsz írj cseho nak aki ha jól tudom az egyik legrégibb Wog os player


Vissza a tetejére
 Profil  
 
  Offline
 Hozzászólás témája:
HozzászólásElküldve: 2004 ápr. 12 hétf., 17:06 
Avatar

Csatlakozott: 2003 júl. 13 vas., 16:10
Hozzászólások: 260
Tartózkodási hely: Szeged
Idézet:
Mik ezek a scriptek és hogy kell őket használni?


Az ERM script az egy olyan "mini program", ami a WoG-ban változtatásokat tud alkalmazni. Gyakorlatilag akármit meg lehet velük változtatni, a lények HP-jétől kezdve azt, hogy mit tegyen a játék, ha odalépsz egy helyre.

A használatuk:
Készítsd el a pályát a WOG map editorja segítségével.
Ha kell egy ilyen script, akkor másold ki a "ZVSE"-től a végéig (ctrl-c).
Ezután a H3WoG-os map editorban illeszd be (ctrl-v) egy timed event szöveges részébe. Állítsd be azt, hogy vagy ne jelenjen meg semelyik játékosnál, vagy pedig nagy legyen a 'Day of first occurrence', hogy ne mutassa meg a játékosoknak. Ha ezzel kész vagy, akkor adj neki nevet, OK-zd le, és ha minden igaz, akkor (csak azon a pályán amelyikbe beillesztetted) meg lesznek azok a változtatások, amiket az ERM sciptek adnak.


Vissza a tetejére
 Profil  
 
Hozzászólások megjelenítése:  Rendezés  
Új téma nyitása Hozzászólás a témához  [ 238 hozzászólás ]  Oldal 1, 2, 3, 4, 5 ... 12  Következő

Időzóna: UTC + 1 óra [ nyi ]


Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 1 vendég


Nem nyithatsz témákat ebben a fórumban.
Nem válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.

Keresés:
Ugrás:  
cron
Powered by phpBB® Forum Software © phpBB Group
Imperium - Modified by Rey phpbbmodrey
Magyar fordítás © Magyar phpBB Közösség